EnigmA Amiga Run 1997 July/EnigmA AMIGA RUN 20 (1997)(G.R. Edizioni)(IT)[!][issue 1997-07 & 08][EAR-CD IV].iso/lightwave/lwmlist/96.lightwave-0215/[e-mail] _Wed Feb 21 15:01:25 1996.msg

Internet Message Format | 1996-02-29 | 8KB

Received: from mail.webcom.com (mail.webcom.com [206.2.192.68]) by keeper.albany.net (8.7.1/8.7.1) with ESMTP id PAA25605 for <[e-mail]>; Wed, 21 Feb 1996 15:01:11 -0500 (EST)
Received: from localhost by mail.webcom.com with SMTP
    (1.37.109.15/16.2) id AA123992937; Wed, 21 Feb 1996 12:02:17 -0800
Date: Wed, 21 Feb 1996 12:02:17 -0800
Errors-To: [e-mail]
Message-Id: <[e-mail]>
Errors-To: [e-mail]
Reply-To: [e-mail]
Originator: [e-mail]
Sender: [e-mail]
Precedence: bulk
From: [e-mail] (robert hood)
To: [e-mail]
Subject: Progress Report: Layout scripting
X-Listprocessor-Version: 6.0c -- ListProcessor by Anastasios Kotsikonas
Status: RO
X-Status:

Sorry to take up bandwidth, but there are individuals on this list that
have expressed an interest in this.

I have made a minor step forward in Layout scripting.  The following
BML ImageFilter script (lengthy because of comments) is fully functional
as I write.  It can even be saved along with a scene file and automatically
reloaded the next time the scene is loaded:

//---------------------------------------------------------------------------
// BML/IF:  Black & White
//
//        Post-process a color frame into black and white.
//
// if a function is not declared, BML/IF will default its behavior.  The
// available ImageFilter scripting functions are:
//
//           process()    called for each frame to process the selected
//                        buffer(s)
//           flags()      called once to specify buffers needed by plugin
//           options()    called to interact with the user
//           create()     called once at plugin startup to perform creation
//                        activities
//           destroy()    called once just prior to plugin removal to
//                        perform shutdown activities
//           load()       called when a scene is loaded that previously
//                        used this script to load stored parameters
//           save()       called when a scene is saved so that the
//                        script may store needed parameters
//
// the plugin interface function copy() is not implemented as the script
// maintains it own data.
//
// NOTE: whether the flags() function is defined or not, ImageFilter scripts
// automatically have access to the RED, GREEN, BLUE, and ALPHA buffers.
//---------------------------------------------------------------------------

var     gamma;  // this needs to be global so all commands can access it

//---------------------------------------------------------------------------
// every process() declaration must accept five arguments

process: width, height, frame, starttime, endtime
{
    var red[width];
    var green[width];
    var blue[width];
    var alpha[width];
    var out[3];
    var i,j;
    var average;

    moninit(height);

    for(i = 0;i < height;++i)
    {
        red   = bufferline(RED,i);
        green = bufferline(GREEN,i);
        blue  = bufferline(BLUE,i);
        alpha = bufferline(ALPHA,i);

        for(j = 1;j <= width;++j)
        {
            if(red[j] == 0 && green[j] == 0 && blue[j] == 0)
                average = 0;
            else
                average = integer((red[j] + green[j] + blue[j]) / 3);

            if(gamma)
            {
                average += gamma;
                if(average < 0)
                    average = 0;
                else if(average > 255)
                    average = 255;
            }

            out[] = average;    // populate the whole array with
                                // the same value

            setrgb(j - 1,i,out);
            setalpha(j - 1,i,alpha[j]);
        }

        if(monstep())
            return;
    }

    monend();
}

//-----------------------------------------------------------------
// we don't really need this function for this plugin, but it is
// here for illustration

flags
{
    // available buffers are:
    // SPECIAL      LUMINOUS        DIFFUSE
    // MIRROR       TRANS           RAWRED
    // RAWGREEN     RAWBLUE         SHADING
    // SHADOW       GEOMETRY        DEPTH
    // (RED)        (GREEN)         (BLUE)      (ALPHA)

    return(RED,GREEN,BLUE,ALPHA);   // select the defaults just for fun  =|^)
}

//-----------------------------------------------------------------
// this command is invoked when the user presses the "Options"
// button on the plugin interface (all BML Layout plugins currently
// employ the Common Plugin Interface (CPI) Toolkit).

options
{
    var c1;

    reqbegin("Black & White");

    c1 = addcontrol(gamma,"Gamma correction");

    if(reqpost())
        gamma = getvalue(c1);

    reqend();
}

//-----------------------------------------------------------------
// create() is invoked as soon as the BML engine plugin is loaded
// and this script is successfully compiled.
//
// a companion command, destroy(), is called when the plugin is
// being shutdown (either by an explicit action of the user, or
// when the Layout session is terminated).  the destroy() command
// is not used in this script because we have no activities that
// need to be performed during a shutdown.

create
{
    // initialize the 'gamma' value (a later load() or options()
    // call may alter it)

    gamma = 0;
}

//-----------------------------------------------------------------
// load() is called when the user loads a scene file where this
// script was active.  the BML engine will automatically reload
// and recompile this script in such a case.  in load(), we need to
// read in our save()'d operating parameters.

load: what,     // 'what' is either SCENE (ASCII) or OBJECT (binary)
      io        // a pseudo-FileObject that only supports a subset of the
                     // full FileObject methods (i.e., random access
                     // functions such as rewind() are not supported)
{
    var line;
    var items[2];

    if(what == SCENE)   // processing an ASCII scene file
    {
        line = nil;     // a return of 'nil' can indicate either a
                        // blank line or eof

        while(line == nil && io.eof() != true)
            line = io.read();

        items = parse(" ",line);

        if(items[1] == "Gamma")
            gamma = integer(items[2]);
    }
    else if(what == OBJECT) // processing a binary LightWave object file
    {
        // we don't grok OBJECT files
    }
}

//-----------------------------------------------------------------
// save() is activated when the user saves a scene file where this
// script is active.  in save(), we need to store our operating
// parameters into the scene file.

save: what, io
{
    if(what == SCENE)       // save our working parameters for a later load
        io.writeln("Gamma ",gamma);
}
//---------------------------------------------------------------------------

Thanks for the bandwidth.

Render me gone,               |||
Bob                         ^(===)^
-------------------------oOO--(_)--OOo--------------------------------------
Bob Hood, President | All governments suffer from a recurring problem:
Virtual Visions,Inc.| Power attracts pathological personalities.  It is not
Tel: [phone] | that power corrupts, but that it is magnetic to the
FAX: [phone] | corruptible.  Such people have a tendency to become
                    | drunk on violence, a condition to which they are
[e-mail]    | quickly addicted              - Frank Herbert
----------------------------------------------------------------------------